ocarina-backends-build_utils.adb 73 KB
Newer Older
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
------------------------------------------------------------------------------
--                                                                          --
--                           OCARINA COMPONENTS                             --
--                                                                          --
--         O C A R I N A . B A C K E N D S . B U I L D _ U T I L S          --
--                                                                          --
--                                 B o d y                                  --
--                                                                          --
--               Copyright (C) 2008-2010, GET-Telecom Paris.                --
--                                                                          --
-- Ocarina  is free software;  you  can  redistribute  it and/or  modify    --
-- it under terms of the GNU General Public License as published by the     --
-- Free Software Foundation; either version 2, or (at your option) any      --
-- later version. Ocarina is distributed  in  the  hope  that it will be    --
-- useful, but WITHOUT ANY WARRANTY;  without even the implied warranty of  --
-- MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General --
-- Public License for more details. You should have received  a copy of the --
-- GNU General Public License distributed with Ocarina; see file COPYING.   --
-- If not, write to the Free Software Foundation, 51 Franklin Street, Fifth --
-- Floor, Boston, MA 02111-1301, USA.                                       --
--                                                                          --
-- As a special exception,  if other files  instantiate  generics from this --
-- unit, or you link  this unit with other files  to produce an executable, --
-- this  unit  does not  by itself cause  the resulting  executable to be   --
-- covered  by the  GNU  General  Public  License. This exception does not  --
-- however invalidate  any other reasons why the executable file might be   --
-- covered by the GNU Public License.                                       --
--                                                                          --
--                 Ocarina is maintained by the Ocarina team                --
--                       (ocarina-users@listes.enst.fr)                     --
--                                                                          --
------------------------------------------------------------------------------

with Ada.Unchecked_Deallocation;

with GNAT.Table;

with GNAT.OS_Lib;
with GNAT.Directory_Operations;

with Namet;
with Output;

with Ocarina.ME_AADL;
with Ocarina.ME_AADL.AADL_Instances.Nodes;
with Ocarina.ME_AADL.AADL_Instances.Nutils;
with Ocarina.Options;                  use Ocarina.Options;
with Ocarina.ME_AADL.AADL_Instances.Entities;
with Ocarina.Backends;                 use Ocarina.Backends;
with Ocarina.Backends.Utils;
with Ocarina.Backends.Messages;
with Ocarina.Backends.Ada_Tree.Nutils;

package body Ocarina.Backends.Build_Utils is

   use GNAT.OS_Lib;
   use GNAT.Directory_Operations;
   use Namet;
   use Output;

   use Ocarina.ME_AADL;
   use Ocarina.ME_AADL.AADL_Instances.Nodes;
   use Ocarina.ME_AADL.AADL_Instances.Entities;
   use Ocarina.Backends.Utils;
   use Ocarina.Backends.Messages;

   package AAU renames Ocarina.ME_AADL.AADL_Instances.Nutils;
   package ADU renames Ocarina.Backends.Ada_Tree.Nutils;

   procedure Split_Path
     (Filename  :     Name_Id;
      Directory :     Name_Id;
      Basename  : out Name_Id;
      Dirname   : out Name_Id);
   --  Dirname and Basename corresponds to Dir_Name and Base_Name of
   --  an intermediate filename. If Filename is an absolute path, this
   --  intermediate filename is Filename. If Filename is a relative
   --  path, the intermediate filename is either relative to
   --  Directory, if Directory is non-null, or to the current working
   --  directory if Directory is null. Directory may be relative to
   --  the current directory in which case it is also normalized.

   function Resolve_Language (E : Node_Id) return Supported_Source_Language;
   --  Fetches the Source_Language property of E. If the property is
   --  not set, try to deduce the language from the current generator.

   generic
      --  This generic package is a generic list to store the "build
      --  utils" (makefiles, project files...). It provides accessor
      --  routines to allow a process node to find its corresponding
      --  "build util".

      type Build_Util is private;
      --  The type of "build util"

      Id : String;
      --  The Id of the generic table. It MUST be a unique string

      with procedure Free (T : in out Build_Util);
      --  For deallocation purpose

   package Generic_List is
      --  This package is a generic list to store the "build utils"
      --  (makefiles, project files...). It provides accessor routines
      --  to allow a process node to find its corresponding "build util".

      procedure Set (P : Node_Id; U : Build_Util);
      function Get (P : Node_Id) return Build_Util;

      procedure Free;
      --  Deallocates the table

      procedure Init;
      --  A call to this procedure is NECESSARY after any call to
      --  Free. It is not necessary before the first use of the table.

   end Generic_List;

   ------------
   -- Length --
   ------------

   function Length (T : Name_Tables.Instance) return Int is
   begin
      return Name_Tables.Last (T) - Name_Tables.First + 1;
   end Length;

   ----------------------
   -- Get_Runtime_Path --
   ----------------------

   function Get_Runtime_Path (Runtime_Name : String) return String is
   begin
      Get_Name_String (Installation_Directory);
      Add_Str_To_Name_Buffer ("include" & Directory_Separator);
      Add_Str_To_Name_Buffer ("ocarina" & Directory_Separator);
      Add_Str_To_Name_Buffer ("runtime" & Directory_Separator);
      Add_Str_To_Name_Buffer (Runtime_Name);

      declare
         Path : constant String := Get_Name_String (Name_Find);
      begin
         if not Is_Directory (Path) then
            Display_Error (Path & " is not a valid runtime directory", True);
         end if;
         return Path;
      end;
   end Get_Runtime_Path;

   ----------------
   -- Split_Path --
   ----------------

   procedure Split_Path
     (Filename  :     Name_Id;
      Directory :     Name_Id;
      Basename  : out Name_Id;
      Dirname   : out Name_Id)
   is
   begin
      if Directory = No_Name then
         Set_Str_To_Name_Buffer (".");
      else
         Get_Name_String (Directory);
      end if;
      declare
         Normalized_Dir : constant String
           := Normalize_Pathname (Name_Buffer (1 .. Name_Len));
         Resolved_Filename : constant String
           := Normalize_Pathname (Get_Name_String (Filename), Normalized_Dir);
      begin
         Dirname  := Get_String_Name (Dir_Name (Resolved_Filename));
         Basename := Get_String_Name (Base_Name (Resolved_Filename));
      end;
   end Split_Path;

   ------------------
   -- Generic_List --
   ------------------

   package body Generic_List is

      package Internal_Table is new GNAT.Table (Build_Util, Nat, 1, 10, 10);
      --  The internal table

      function Get_Internal_Name (P : Node_Id) return Name_Id;
      --  For code factorization purpose

      -----------------------
      -- Get_Internal_Name --
      -----------------------

      function Get_Internal_Name (P : Node_Id) return Name_Id is
      begin
         pragma Assert (AAU.Is_Process (P));

         Set_Nat_To_Name_Buffer (Nat (P));
         Add_Str_To_Name_Buffer ('%' & Id & '%');
         return Name_Find;
      end Get_Internal_Name;

      ---------
      -- Set --
      ---------

      procedure Set (P : Node_Id; U : Build_Util) is
         I_Name : constant Name_Id := Get_Internal_Name (P);
      begin
         Internal_Table.Append (U);
         Set_Name_Table_Info (I_Name, Internal_Table.Last);
      end Set;

      ---------
      -- Get --
      ---------

      function Get (P : Node_Id) return Build_Util is
         I_Name : constant Name_Id := Get_Internal_Name (P);
         Index  : constant Nat := Get_Name_Table_Info (I_Name);
      begin
         if Index = 0 then
            raise Program_Error with "Try to get a build utils which has"
              & " not been set";
         end if;

         return Internal_Table.Table (Index);
      end Get;

      ----------
      -- Init --
      ----------

      procedure Init is
      begin
         Internal_Table.Init;
      end Init;

      ----------
      -- Free --
      ----------

      procedure Free is
      begin
         for J in Internal_Table.First .. Internal_Table.Last loop
            Free (Internal_Table.Table (J));
         end loop;

         Internal_Table.Free;
         Internal_Table.Init;
      end Free;
   end Generic_List;

   ----------------------
   -- Resolve_Language --
   ----------------------

   function Resolve_Language (E : Node_Id) return Supported_Source_Language is
      Language : Supported_Source_Language := Get_Source_Language (E);
   begin
      --  If the user did not specify a language for E, we assume that
      --  the language is the current generator one.

      if Language = Language_None then
         case Get_Current_Backend_Kind is
            when PolyORB_QoS_Ada |
              PolyORB_HI_Ada =>
               Language := Language_Ada_95;

            when PolyORB_HI_C =>
               Language := Language_C;

            when PolyORB_HI_RTSJ =>
               Language := Language_RTSJ;

            when others =>
               raise Program_Error;
         end case;
      end if;

      return Language;
   end Resolve_Language;

   ---------------
   -- Makefiles --
   ---------------

   package body Makefiles is

      procedure Visit_Architecture_Instance (E : Node_Id);
      procedure Visit_Component_Instance    (E : Node_Id);
      procedure Visit_System_Instance       (E : Node_Id);
      procedure Visit_Process_Instance      (E : Node_Id);
      procedure Visit_Thread_Instance       (E : Node_Id);
      procedure Visit_Subprogram_Instance   (E : Node_Id);
      procedure Visit_Port_Instance         (E : Node_Id);

      procedure Build_Architecture_Instance (E : Node_Id);
      procedure Build_Component_Instance    (E : Node_Id);
      procedure Build_System_Instance       (E : Node_Id);
      procedure Build_Process_Instance      (E : Node_Id);

      procedure Clean_Architecture_Instance (E : Node_Id);
      procedure Clean_Component_Instance    (E : Node_Id);
      procedure Clean_System_Instance       (E : Node_Id);

      type Makefile_Rec is record
         Appli_Name         : Name_Id;
         --  The distributed application name

         Node_Name          : Name_Id;
         --  The node name (in lower case)

         Execution_Platform : Supported_Execution_Platform := Platform_None;
         --  The execution platform of the processor the current node
         --  is bound to.

         Transport_API      : Supported_Transport_APIs;
         --  The transport API used by the current node to
         --  communicate with other nodes.

         C_Objs             : Name_Tables.Instance;

         Ada_Sources        : Name_Tables.Instance;

         C_Sources          : Name_Tables.Instance;
         --  The C source files that may implement some subprograms of
         --  the current node (absolute or relative path).

         C_Libraries        : Name_Tables.Instance;
         --  The C libraries that may contain the binary code of some
         --  subprograms of the current node (absolute or relative
         --  path).

         User_Source_Dirs : Name_Tables.Instance;
         --  Directories of the source files provided by the user

         Use_Transport : Boolean;
         --  Use_Transport is used to know if the node has in or out
         --  port If it uses transport, the C Makefiles will contain
         --  something like NEED_TRANSPORT = [yes|no]. It is used to
         --  know if the files that handle transport in PolyORB-HI-C
         --  should be compiled or not.

         Simulink_Directory : Name_Id;
         --  The Simulink_Directory corresponds to the directory
         --  that contains the simulink application code.

         Simulink_Node      : Name_Id;
         --  The Simulink_Node is the name of the node we try to
         --  integrate in our AADL model.

         Use_Simulink       : Boolean;
         --  Use_Simulink states if we integrate simulink application
         --  code or not.

         Scade_Directory    : Name_Id;
         --  The Scade_Directory is the name of the directory that contains
         --  Scade source code.

         Use_Scade          : Boolean;
         --  The Use_Scade variable tells the build-system if we try
         --  to integrate SCADE application code in our generated
         --  system.

      end record;
      --  This structure gathers all the information needed to
      --  generate a makefile for a given node of the distributed
      --  application.

      type Makefile_Type is access all Makefile_Rec;

      procedure Free (M : in out Makefile_Type);
      --  Deallocates the internals of T

      procedure Ada_C_Command_Line_Flags
        (Ada_Sources        : Name_Tables.Instance;
         C_Sources          : Name_Tables.Instance;
         C_Libraries        : Name_Tables.Instance);

      procedure Compile_Ada_Files (Ada_Sources : Name_Tables.Instance);

      procedure Compile_C_Files (C_Sources : Name_Tables.Instance);
      --  Generate a makefile target to compile C_Sources C files

      procedure Handle_C_Source
        (E            : Node_Id;
         Implem_Name  : Name_Id;
         Source_Files : Name_Array;
         M            : Makefile_Type);
      --  Update the makefile structure by adding necessary paths to
      --  sources or libraries provided by the 'Source_Files' array. E
      --  is the node for which the source files are given, it is used
      --  to resolve relative paths through its absolute location.

      procedure Handle_Ada_Source
        (E            : Node_Id;
         Implem_Name  : Name_Id;
         Source_Files : Name_Array;
         M            : Makefile_Type);
      --  Update the makefile structure by adding necessary paths to
      --  sources or libraries provided by the 'Source_Files' array. E
      --  is the node for which the source files are given, it is used
      --  to resolve relative paths through its absolute location.

      ----------
      -- Free --
      ----------

      procedure Free (M : in out Makefile_Type) is
         procedure Deallocate is new Ada.Unchecked_Deallocation
           (Makefile_Rec, Makefile_Type);
      begin
         Name_Tables.Free (M.all.Ada_Sources);
         Name_Tables.Free (M.all.C_Objs);
         Name_Tables.Free (M.all.C_Sources);
         Name_Tables.Free (M.all.C_Libraries);
         Name_Tables.Free (M.all.User_Source_Dirs);

         Deallocate (M);
      end Free;

      package Makefiles is new Generic_List
        (Makefile_Type, "Makefile_List", Free);
      --  The list of all the makefile structures

      -----------
      -- Reset --
      -----------

      procedure Reset is
      begin
         Makefiles.Free;
      end Reset;

      -----------------------
      -- Handle_Ada_Source --
      -----------------------

      procedure Handle_Ada_Source
        (E            : Node_Id;
         Implem_Name  : Name_Id;
         Source_Files : Name_Array;
         M            : Makefile_Type)
      is
         Source_Basename : Name_Id;
         Source_Dirname  : Name_Id;
         S_Name          : Name_Id;

      begin
         --  Ensure the user gives at most one source file (.adb)

         if Source_Files'Length > 2 then
            Display_Located_Error
              (Loc (E),
               "cannot have more than two source files for an Ada subprogram",
               Fatal => True);

         elsif Source_Files'Length /= 0 and then Implem_Name /= No_Name then
            for J in Source_Files'Range loop
               --  Ensure the source is added only once per node

               Get_Name_String (Source_Files (J));
               Get_Name_String_And_Append (M.Node_Name);
               Add_Str_To_Name_Buffer ("%source_text%");
               S_Name := Name_Find;

               if Get_Name_Table_Info (S_Name) = 0 then
                  Set_Name_Table_Info (S_Name, 1);

                  Get_Name_String (Source_Files (J));

                  Split_Path
                    (Source_Files (J),
                     Loc (E).Dir_Name,
                     Source_Basename,
                     Source_Dirname);

                  Get_Name_String (Source_Basename);

                  if Name_Buffer (Name_Len - 3 .. Name_Len) = ".adb" then
                     Get_Name_String (Source_Dirname);
                     Get_Name_String_And_Append (Source_Basename);

                     Name_Tables.Append (M.Ada_Sources, Name_Find);
                  end if;
               end if;
            end loop;
         end if;
      end Handle_Ada_Source;

      ---------------------
      -- Handle_C_Source --
      ---------------------

      procedure Handle_C_Source
        (E            : Node_Id;
         Implem_Name  : Name_Id;
         Source_Files : Name_Array;
         M            : Makefile_Type)
      is
         Source_Basename : Name_Id;
         Source_Dirname  : Name_Id;
         S_Name          : Name_Id;
         Binding_Key     : constant String := "%user_src_dir%";

      begin
         --  Ensure the user gives at most one source file (.c)

         if Source_Files'Length > 1 and then
            Get_Current_Backend_Kind = PolyORB_HI_Ada then
            Display_Located_Error
              (Loc (E),
               "more than one source files for a C subprogram",
               Fatal => True);
         end if;

         if Source_Files'Length = 0 and then Implem_Name /= No_Name then
            --  This means that the user did not provide source file
            --  names for the C implementation but did provide the
            --  implementation name. Therefore, the corresponding
            --  source files have conventional names and are located
            --  at the same directory as the AADL file.

            Split_Path
              (Implem_Name,
               Loc (E).Dir_Name,
               Source_Basename,
               Source_Dirname);

            Set_Str_To_Name_Buffer (Binding_Key);
            Get_Name_String_And_Append (Source_Dirname);
            Get_Name_String_And_Append (M.Node_Name);

            if Get_Name_Table_Byte (Name_Find) = 0 then
               Name_Tables.Append
                 (M.User_Source_Dirs,
                  Source_Dirname);
               Set_Name_Table_Byte (Name_Find, 1);
            end if;

         elsif Source_Files'Length /= 0 and then Implem_Name /= No_Name then
            for J in Source_Files'Range loop
               --  Ensure the source is added only once per node

               Get_Name_String (Source_Files (J));
               Get_Name_String_And_Append (M.Node_Name);
               Add_Str_To_Name_Buffer ("%source_text%");
               S_Name := Name_Find;

               if Get_Name_Table_Info (S_Name) = 0 then
                  Set_Name_Table_Info (S_Name, 1);

                  Get_Name_String (Source_Files (J));

                  Split_Path
                    (Source_Files (J),
                     Loc (E).Dir_Name,
                     Source_Basename,
                     Source_Dirname);

                  Get_Name_String (Source_Basename);

                  if Name_Buffer (Name_Len - 1 .. Name_Len) = ".o"
                    or else Name_Buffer (Name_Len - 1 .. Name_Len) = ".a"
                  then
                     --  Library names MUST begin with "lib"

                     if Name_Buffer (Name_Len - 1 .. Name_Len) = ".a"
                       and then (Name_Len <= 5
                                   or else Name_Buffer (1 .. 3) /= "lib")
                     then
                        Display_Error
                          ("Invalid library name"
                             & Name_Buffer (1 .. Name_Len),
                           Fatal => True);
                     end if;

                     Get_Name_String (Source_Dirname);
                     Get_Name_String_And_Append (Source_Basename);

                     Name_Tables.Append (M.C_Libraries, Name_Find);

                  elsif Name_Buffer (Name_Len - 1 .. Name_Len) = ".c" then
                     Get_Name_String (Source_Dirname);
                     Get_Name_String_And_Append (Source_Basename);

                     Name_Tables.Append (M.C_Sources, Name_Find);

                     Set_Str_To_Name_Buffer (Binding_Key);
                     Get_Name_String (Source_Dirname);
                     Get_Name_String_And_Append (M.Node_Name);

                     if Get_Name_Table_Byte (Name_Find) = 0 then
                        Name_Tables.Append
                          (M.User_Source_Dirs,
                           Source_Dirname);
                        Set_Name_Table_Byte (Name_Find, 1);
                     end if;
                  else
                     Set_Str_To_Name_Buffer (Binding_Key);
                     Get_Name_String (Source_Dirname);
                     Get_Name_String_And_Append (M.Node_Name);

                     if Get_Name_Table_Byte (Name_Find) = 0 then
                        Name_Tables.Append
                          (M.User_Source_Dirs,
                           Source_Dirname);
                        Set_Name_Table_Byte (Name_Find, 1);
                     end if;
                  end if;
               end if;
            end loop;
         end if;
      end Handle_C_Source;

      -----------
      -- Visit --
      -----------

      procedure Visit (E : Node_Id) is
      begin
         case Kind (E) is
            when K_Architecture_Instance =>
               Visit_Architecture_Instance (E);

            when K_Component_Instance =>
               Visit_Component_Instance (E);

            when K_Port_Spec_Instance =>
               Visit_Port_Instance (E);

            when others =>
               null;
         end case;
      end Visit;

      ---------------------------------
      -- Visit_Architecture_Instance --
      ---------------------------------

      procedure Visit_Architecture_Instance (E : Node_Id) is
      begin
         Visit (Root_System (E));
      end Visit_Architecture_Instance;

      ------------------------------
      -- Visit_Component_Instance --
      ------------------------------

      procedure Visit_Component_Instance (E : Node_Id) is
         Category : constant Component_Category
           := Get_Category_Of_Component (E);
      begin
         case Category is
            when CC_System =>
               Visit_System_Instance (E);

            when CC_Process =>
               Visit_Process_Instance (E);

            when CC_Thread =>
               Visit_Thread_Instance (E);

            when CC_Subprogram =>
               Visit_Subprogram_Instance (E);

            when others =>
               null;
         end case;
      end Visit_Component_Instance;

      ----------------------------
      -- Visit_Process_Instance --
      ----------------------------

      procedure Visit_Process_Instance (E : Node_Id) is
         S  : constant Node_Id := Parent_Subcomponent (E);
         A  : constant Node_Id := Parent_Component (Parent_Subcomponent (E));
         M  : constant Makefile_Type := new Makefile_Rec;
         SC : Node_Id;
      begin
         --  Associates the Makefile structure to the process
         --  instance. Keep in mind that it is important to use
         --  accesses here because all the visited threads and
         --  subprgrams will fetch this access to update the
         --  corresponding structure.

         Makefiles.Set (E, M);

         M.Appli_Name := Normalize_Name (Name (Identifier (A)));
         M.Node_Name  := Normalize_Name (Name (Identifier (S)));
         M.Use_Transport := False;
         M.Use_Simulink  := False;

         --  Get the execution platform of the processor this node is
         --  bound to.

         M.Execution_Platform := Get_Execution_Platform
           (Get_Bound_Processor (E));

         --  Get the transport API used by this node. It is
         --  important to ensure that the Namings package visitors
         --  have already been executed since they perform all
         --  consistency checks and bind a node to its transport
         --  API.

         M.Transport_API := Fetch_Transport_API (E);

         --  Initialize the lists

         Name_Tables.Init (M.Ada_Sources);
         Name_Tables.Init (M.C_Sources);
         Name_Tables.Init (M.C_Objs);
         Name_Tables.Init (M.C_Libraries);
         Name_Tables.Init (M.User_Source_Dirs);

         --  Visit all the subcomponents of the process

         if not AAU.Is_Empty (Subcomponents (E)) then
            SC := First_Node (Subcomponents (E));

            while Present (SC) loop
               --  Visit the corresponding instance of SC

               Visit (Corresponding_Instance (SC));

               SC := Next_Node (SC);
            end loop;
         end if;
      end Visit_Process_Instance;

      ---------------------------
      -- Visit_System_Instance --
      ---------------------------

      procedure Visit_System_Instance (E : Node_Id) is
         S : Node_Id;
      begin
         --  Visit all the subcomponents of the system

         if not AAU.Is_Empty (Subcomponents (E)) then
            S := First_Node (Subcomponents (E));
            while Present (S) loop
               --  Visit the component instance corresponding to the
               --  subcomponent S.

               Visit (Corresponding_Instance (S));
               S := Next_Node (S);
            end loop;
         end if;
      end Visit_System_Instance;

      ---------------------------
      -- Visit_Thread_Instance --
      ---------------------------

      procedure Visit_Thread_Instance (E : Node_Id) is
         Parent_Process : constant Node_Id :=
           Corresponding_Instance (Get_Container_Process (E));
         M              : constant Makefile_Type :=
           Makefiles.Get (Parent_Process);
         Compute_Entrypoint : Name_Id;
         Initialize_Entrypoint : constant Name_Id :=
           Get_Thread_Initialize_Entrypoint (E);
         Language       : constant Supported_Source_Language :=
           Resolve_Language (E);
         Source_Files   : constant Name_Array := Get_Source_Text (E);
         Call_Seq       : Node_Id;
         Spg_Call       : Node_Id;
         F              : Node_Id;
      begin
         --  If the thread implementation is in C, we need to update
         --  the makefile structure.

         if Language = Language_C then
            Compute_Entrypoint := Get_Thread_Compute_Entrypoint (E);
            Handle_C_Source (E, Compute_Entrypoint, Source_Files, M);
            Handle_C_Source (E, Initialize_Entrypoint, Source_Files, M);
         end if;

         --  Visit the features of the thread for possible source
         --  files.

         if not AAU.Is_Empty (Features (E)) then
            F := First_Node (Features (E));

            while Present (F) loop
               if Kind (F) = K_Port_Spec_Instance then
                  M.Use_Transport := True;
                  if Is_In (F) then
                     Visit (F);
                  end if;
               end if;

               F := Next_Node (F);
            end loop;
         end if;

         --  Visit all the call sequences of the thread

         if not AAU.Is_Empty (Calls (E)) then
            Call_Seq := First_Node (Calls (E));

            while Present (Call_Seq) loop
               --  For each call sequence visit all the called
               --  subprograms.

               if not AAU.Is_Empty (Subprogram_Calls (Call_Seq)) then
                  Spg_Call := First_Node (Subprogram_Calls (Call_Seq));

                  while Present (Spg_Call) loop
                     Visit (Corresponding_Instance (Spg_Call));

                     Spg_Call := Next_Node (Spg_Call);
                  end loop;
               end if;

               Call_Seq := Next_Node (Call_Seq);
            end loop;
         end if;
      end Visit_Thread_Instance;

      -------------------------------
      -- Visit_Subprogram_Instance --
      -------------------------------

      procedure Visit_Subprogram_Instance (E : Node_Id) is
         Parent_Process  : constant Node_Id :=
           Corresponding_Instance (Get_Container_Process (E));
         M               : constant Makefile_Type :=
           Makefiles.Get (Parent_Process);
         Subprogram_Kind : constant Supported_Subprogram_Kind :=
           Get_Subprogram_Kind (E);
         Source_Name     : constant Name_Id := Get_Source_Name (E);
         Source_Files    : constant Name_Array := Get_Source_Text (E);
         Call_Seq        : Node_Id;
         Spg_Call        : Node_Id;
         Simulink_Dir    : Name_Id;
         Scade_Dir       : Name_Id;
      begin
         --  Only C subprogram influence the structure of the
         --  generated makefile.

         case Subprogram_Kind is
            when Subprogram_Opaque_C =>
               --  If the subprogram is implemented by C source files,
               --  add the files to the C_Files list of the makefile
               --  structure. If the subprogram is implemented by a C
               --  library, add the files to the C_Libraries list of
               --  the makefile structure.

               Handle_C_Source (E, Source_Name, Source_Files, M);

            when Subprogram_Opaque_Ada_95 =>
               --  If the subprogram is implemented by Ada source files,
               --  add the files to the Ada_Files list of the makefile
               --  structure.

               Handle_Ada_Source (E, Source_Name, Source_Files, M);

            when Subprogram_Scade =>
               Scade_Dir := Source_Files (1);
               M.Use_Scade := True;
               M.Scade_Directory := Scade_Dir;

            when Subprogram_Simulink =>
               Simulink_Dir := Source_Files (1);

               M.Use_Simulink := True;

               M.Simulink_Directory := Simulink_Dir;
               M.Simulink_Node      := Source_Name;

               Set_Str_To_Name_Buffer ("");
               Get_Name_String (Simulink_Dir);
               Add_Str_To_Name_Buffer ("/");
               Add_Str_To_Name_Buffer ("/*.o");
               Name_Tables.Append
                  (M.C_Objs, Name_Find);

            when others =>
               null;
         end case;

         --  Visit all the call sequences of the subprogram

         if not AAU.Is_Empty (Calls (E)) then
            Call_Seq := First_Node (Calls (E));

            while Present (Call_Seq) loop
               --  For each call sequence visit all the called
               --  subprograms.

               if not AAU.Is_Empty (Subprogram_Calls (Call_Seq)) then
                  Spg_Call := First_Node (Subprogram_Calls (Call_Seq));

                  while Present (Spg_Call) loop
                     Visit (Corresponding_Instance (Spg_Call));

                     Spg_Call := Next_Node (Spg_Call);
                  end loop;
               end if;

               Call_Seq := Next_Node (Call_Seq);
            end loop;
         end if;
      end Visit_Subprogram_Instance;

      -------------------------
      -- Visit_Port_Instance --
      -------------------------

      procedure Visit_Port_Instance (E : Node_Id) is
         Parent_Process : constant Node_Id := Corresponding_Instance
           (Get_Container_Process
            (Parent_Component (E)));
         M              : constant Makefile_Type := Makefiles.Get
           (Parent_Process);
         Language       : constant Supported_Source_Language :=
           Resolve_Language (E);
         Compute_Entrypoint : constant Name_Id :=
           Get_Port_Compute_Entrypoint (E);
         Source_Files   : constant Name_Array := Get_Source_Text (E);
         Data : Node_Id;
      begin
         --  If the port implementation is in C, we need to update
         --  the makefile structure.

         if Language = Language_C then
            Handle_C_Source (E, Compute_Entrypoint, Source_Files, M);
         end if;

         if Is_Data (E) then
            Data := Corresponding_Instance (E);

            if Get_Source_Language (Data) = Language_Simulink then
               declare
                  Source_Text : constant Name_Array := Get_Source_Text (Data);
               begin

                  M.Use_Simulink := True;

                  if Source_Text'Length /= 0 then
                     M.Simulink_Directory := Source_Text (1);
                  end if;

                  if Get_Source_Name (Data) /= No_Name then
                     M.Simulink_Node      := Get_Source_Name (Data);
                  end if;
               end;

            else
               declare
                  Source_Name : constant Name_Id
                    := Get_Type_Source_Name (Data);
                  Source_Files : constant Name_Array
                    := Get_Source_Text (Data);
               begin
                  Handle_C_Source (E, Source_Name, Source_Files, M);
               end;
            end if;

         end if;
      end Visit_Port_Instance;

      --------------
      -- Generate --
      --------------

      procedure Generate (E : Node_Id) is

         procedure Generate_Architecture_Instance (E : Node_Id);
         procedure Generate_Component_Instance    (E : Node_Id);
         procedure Generate_System_Instance       (E : Node_Id);
         procedure Generate_Process_Instance      (E : Node_Id);

         ------------------------------------
         -- Generate_Architecture_Instance --
         ------------------------------------

         procedure Generate_Architecture_Instance (E : Node_Id) is
         begin
            Generate (Root_System (E));
         end Generate_Architecture_Instance;

         ---------------------------------
         -- Generate_Component_Instance --
         ---------------------------------

         procedure Generate_Component_Instance (E : Node_Id) is
            Category : constant Component_Category
              := Get_Category_Of_Component (E);
         begin
            case Category is
               when CC_System =>
                  Generate_System_Instance (E);

               when CC_Process =>
                  Generate_Process_Instance (E);