ocarina-backends-properties.adb

------------------------------------------------------------------------------
--                                                                          --
--                           OCARINA COMPONENTS                             --
--                                                                          --
--          O C A R I N A . B A C K E N D S . P R O P E R T I E S           --
--                                                                          --
--                                 B o d y                                  --
--                                                                          --
--    Copyright (C) 2008-2009 Telecom ParisTech, 2010-2016 ESA & ISAE.      --
--                                                                          --
-- Ocarina  is free software; you can redistribute it and/or modify under   --
-- terms of the  GNU General Public License as published  by the Free Soft- --
-- ware  Foundation;  either version 3,  or (at your option) any later ver- --
-- sion. Ocarina is distributed in the hope that it will be useful, but     --
-- WITHOUT ANY WARRANTY; without even the implied warranty of               --
-- MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.                     --
--                                                                          --
-- As a special exception under Section 7 of GPL version 3, you are granted --
-- additional permissions described in the GCC Runtime Library Exception,   --
-- version 3.1, as published by the Free Software Foundation.               --
--                                                                          --
-- You should have received a copy of the GNU General Public License and    --
-- a copy of the GCC Runtime Library Exception along with this program;     --
-- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
-- <http://www.gnu.org/licenses/>.                                          --
--                                                                          --
--                 Ocarina is maintained by the TASTE project               --
--                      (taste-users@lists.tuxfamily.org)                   --
--                                                                          --
------------------------------------------------------------------------------

with Locations;
with Ocarina.Namet;
with Utils; use Utils;

with Ocarina.ME_AADL.AADL_Tree.Nodes;
with Ocarina.ME_AADL.AADL_Tree.Nutils;
with Ocarina.ME_AADL.AADL_Instances.Nodes;
with Ocarina.ME_AADL.AADL_Instances.Entities;
with Ocarina.ME_AADL.AADL_Instances.Nutils;
with Ocarina.ME_AADL.AADL_Instances.Entities.Properties;
with Ocarina.ME_AADL.AADL_Tree.Entities.Properties;
with Ocarina.ME_AADL.AADL_Tree.Entities;
with Ocarina.AADL_Values;
with Ocarina.Instances.Queries;
with Ocarina.Backends.Utils;
with Ocarina.Backends.Messages;

with Ocarina.Backends.Properties.Utils; use Ocarina.Backends.Properties.Utils;

package body Ocarina.Backends.Properties is

   use Locations;
   use Ocarina.Namet;
   use Ocarina.ME_AADL.AADL_Tree.Nodes;
   use Ocarina.ME_AADL.AADL_Instances.Nodes;
   use Ocarina.ME_AADL.AADL_Instances.Nutils;
   use Ocarina.ME_AADL.AADL_Instances.Entities;
   use Ocarina.ME_AADL.AADL_Instances.Entities.Properties;
   use Ocarina.Instances.Queries;
   use Ocarina.Backends.Utils;
   use Ocarina.Backends.Messages;

   package ATN renames Ocarina.ME_AADL.AADL_Tree.Nodes;
   package ATE renames Ocarina.ME_AADL.AADL_Tree.Entities;
   package ATNU renames Ocarina.ME_AADL.AADL_Tree.Nutils;
   package AIN renames Ocarina.ME_AADL.AADL_Instances.Nodes;
   package AINU renames Ocarina.ME_AADL.AADL_Instances.Nutils;
   package AIEP renames Ocarina.ME_AADL.AADL_Instances.Entities.Properties;
   package ATEP renames Ocarina.ME_AADL.AADL_Tree.Entities.Properties;

   ----------------------------------
   -- Several component properties --
   ----------------------------------

   AADL_Priority : Name_Id;
   --  Thread and Data

   Compute_Entrypoint_Source_Text_Name : Name_Id;
   Compute_Entrypoint_Name             : Name_Id;
   Compute_Entrypoint_Call_Sequence    : Name_Id;
   --  Thread and IN [event] [data] ports

   Source_Language  : Name_Id;
   Source_Name      : Name_Id;
   T_Source_Name    : Name_Id;
   Type_Source_Name : Name_Id;
   Source_Text      : Name_Id;
   Fusion_Occurred  : Name_Id;
   Priority_Shifter : Name_Id;
   Scheduler_Name   : Name_Id;
   Original_Name    : Name_Id;
   --  Subprogram, thread, data, port...

   Implemented_As     : Name_Id;
   Device_Driver_Name : Name_Id;

   -------------------------------
   -- Data component properties --
   -------------------------------

   Base_Type                 : Name_Id;
   Base_Address              : Name_Id;
   Memory_Size               : Name_Id;
   Code_Set                  : Name_Id;
   Data_Digits               : Name_Id;
   Data_Scale                : Name_Id;
   Data_Representation       : Name_Id;
   Dimension                 : Name_Id;
   Element_Names             : Name_Id;
   Enumerators               : Name_Id;
   IEEE754_Precision         : Name_Id;
   Initial_Value             : Name_Id;
   Integer_Range             : Name_Id;
   Measurement_Unit          : Name_Id;
   Number_Representation     : Name_Id;
   Real_Range                : Name_Id;
   Data_Required_Access      : Name_Id;
   Data_Provided_Access      : Name_Id;
   Source_Data_Size          : Name_Id;
   Data_Size                 : Name_Id;
   Code_Size                 : Name_Id;
   Data_Concurrency_Protocol : Name_Id;

   ---------------------------------
   -- Thread component properties --
   ---------------------------------

   Dispatch_Offset                       : Name_Id;
   Thread_Period                         : Name_Id;
   Thread_Dispatch_Absolute_Time         : Name_Id;
   Thread_Cheddar_Dispatch_Absolute_Time : Name_Id;
   Thread_Deadline                       : Name_Id;
   Thread_Dispatch_Protocol              : Name_Id;
   Thread_Cheddar_Priority               : Name_Id;
   Thread_Stack_Size                     : Name_Id;
   Activate_Entrypoint                   : Name_Id;
   Activate_Entrypoint_Source_Text       : Name_Id;
   Initialize_Entrypoint                 : Name_Id;
   Initialize_Entrypoint_Source_Text     : Name_Id;
   Recover_Entrypoint                    : Name_Id;
   Recover_Entrypoint_Source_Text        : Name_Id;

   POSIX_Scheduling_Policy         : Name_Id;
   Cheddar_POSIX_Scheduling_Policy : Name_Id;
   SCHED_FIFO_Name                 : Name_Id;
   SCHED_RR_Name                   : Name_Id;
   SCHED_Others_Name               : Name_Id;

   ----------------------------------
   -- Process component properties --
   ----------------------------------

   Port_Number       : Name_Id;
   Processor_Binding : Name_Id;
   Function_Binding  : Name_Id;
   Memory_Binding    : Name_Id;

   Scheduling_Protocol                                   : Name_Id;
   PARAMETRIC_PROTOCOL_Name                              : Name_Id;
   EDF_Name                                              : Name_Id;
   EARLIEST_DEADLINE_FIRST_PROTOCOL_Name                 : Name_Id;
   LEAST_LAXITY_FIRST_PROTOCOL_Name                      : Name_Id;
   RMS_Name                                              : Name_Id;
   RATE_MONOTONIC_PROTOCOL_Name                          : Name_Id;
   DEADLINE_MONOTONIC_PROTOCOL_Name                      : Name_Id;
   ROUND_ROBIN_PROTOCOL_Name                             : Name_Id;
   TIME_SHARING_BASED_ON_WAIT_TIME_PROTOCOL_Name         : Name_Id;
   POSIX_1003_HIGHEST_PRIORITY_FIRST_PROTOCOL_Name       : Name_Id;
   D_OVER_PROTOCOL_Name                                  : Name_Id;
   MAXIMUM_URGENCY_FIRST_BASED_ON_LAXITY_PROTOCOL_Name   : Name_Id;
   MAXIMUM_URGENCY_FIRST_BASED_ON_DEADLINE_PROTOCOL_Name : Name_Id;
   TIME_SHARING_BASED_ON_CPU_USAGE_PROTOCOL_Name         : Name_Id;
   NO_SCHEDULING_PROTOCOL_Name                           : Name_Id;
   HIERARCHICAL_CYCLIC_PROTOCOL_Name                     : Name_Id;
   HIERARCHICAL_ROUND_ROBIN_PROTOCOL_Name                : Name_Id;
   HIERARCHICAL_FIXED_PRIORITY_PROTOCOL_Name             : Name_Id;
   HIERARCHICAL_PARAMETRIC_PROTOCOL_Name                 : Name_Id;

   ---------------------------------
   -- Memory component properties --
   ---------------------------------

   Byte_Count : Name_Id;
   Word_Size  : Name_Id;

   ------------------------------------
   -- Processor component properties --
   ------------------------------------

   Ada_Runtime               : Name_Id;
   User_CFLAGS               : Name_Id;
   User_LDFLAGS              : Name_Id;
   Location                  : Name_Id;
   Execution_Platform        : Name_Id;
   Scheduler_Quantum         : Name_Id;
   Cheddar_Scheduler_Quantum : Name_Id;

   Frequency_Hz_Name         : Name_Id;
   Frequency_Khz_Name        : Name_Id;
   Frequency_Mhz_Name        : Name_Id;
   Frequency_Ghz_Name        : Name_Id;
   Processor_Frequency_Name  : Name_Id;

   ---------------------------------
   -- AADL Connections properties --
   ---------------------------------

   Connection_Binding : Name_Id;

   -------------------------------
   -- Bus components properties --
   -------------------------------

   Transport_API : Name_Id;

   ---------------------
   -- Port properties --
   ---------------------

   Queue_Size                                 : Name_Id;
   Overflow_Handling_Protocol                 : Name_Id;
   Overflow_Handling_Protocol_DropOldest_Name : Name_Id;
   Overflow_Handling_Protocol_DropNewest_Name : Name_Id;
   Overflow_Handling_Protocol_Error_Name      : Name_Id;
   Port_Urgency                               : Name_Id;
   Port_Timing                                : Name_Id;
   Port_Timing_Sampled_Name                   : Name_Id;
   Port_Timing_Immediate_Name                 : Name_Id;
   Port_Timing_Delayed_Name                   : Name_Id;

   ---------------------------------
   -- System component properties --
   ---------------------------------

   Protocol : Name_Id;

   --  All the Name_Id's below MUST be initialized in the Init
   --  procedure.

   Data_Array_Name     : Name_Id;
   Data_Boolean_Name   : Name_Id;
   Data_Character_Name : Name_Id;
   Data_Enum_Name      : Name_Id;
   Data_Float_Name     : Name_Id;
   Data_Fixed_Name     : Name_Id;
   Data_Integer_Name   : Name_Id;
   Data_String_Name    : Name_Id;
   Data_Struct_Name    : Name_Id;
   Data_Union_Name     : Name_Id;

   Access_Read_Only_Name  : Name_Id;
   Access_Write_Only_Name : Name_Id;
   Access_Read_Write_Name : Name_Id;
   Access_By_Method_Name  : Name_Id;

   Language_Ada_Name             : Name_Id;
   Language_Ada_95_Name          : Name_Id;
   Language_Ada_05_Name          : Name_Id;
   Language_ASN1_Name            : Name_Id;
   Language_C_Name               : Name_Id;
   Language_CPP_Name             : Name_Id;
   Language_SDL_OpenGEODE_Name   : Name_Id;
   Language_Device_Name          : Name_Id;
   Language_Esterel_Name         : Name_Id;
   Language_GUI_Name             : Name_Id;
   Language_LUA_Name             : Name_Id;
   Language_Lustre_Name          : Name_Id;
   Language_Lustre5_Name         : Name_Id;
   Language_Lustre6_Name         : Name_Id;
   Language_Rhapsody_Name        : Name_Id;
   Language_RTDS_Name            : Name_Id;
   Language_RTSJ_Name            : Name_Id;
   Language_Scade_Name           : Name_Id;
   Language_SCADE6_Name          : Name_Id;
   Language_SDL_Name             : Name_Id;
   Language_SDL_ObjectGeode_Name : Name_Id;
   Language_SDL_RTDS_Name        : Name_Id;
   Language_Simulink_Name        : Name_Id;
   Language_System_C_Name        : Name_Id;
   Language_VHDL_Name            : Name_Id;
   Language_VDM_Name             : Name_Id;
   Language_QGenAda_Name         : Name_Id;
   Language_QGenC_Name           : Name_Id;

   Thread_Periodic_Name   : Name_Id;
   Thread_Aperiodic_Name  : Name_Id;
   Thread_Sporadic_Name   : Name_Id;
   Thread_Hybrid_Name     : Name_Id;
   Thread_Timed_Name      : Name_Id;
   Thread_Interrupt_Name  : Name_Id;
   Thread_Background_Name : Name_Id;

   Time_Ps_Name  : Name_Id;
   Time_Ns_Name  : Name_Id;
   Time_Us_Name  : Name_Id;
   Time_Ms_Name  : Name_Id;
   Time_Sec_Name : Name_Id;
   Time_Min_Name : Name_Id;
   Time_Hr_Name  : Name_Id;

   Size_Bit_Name       : Name_Id;
   Size_Byte_Name      : Name_Id;
   Size_Kilo_Byte_Name : Name_Id;
   Size_Mega_Byte_Name : Name_Id;
   Size_Giga_Byte_Name : Name_Id;
   Size_Tera_Byte_Name : Name_Id;

   Platform_Native_Name                 : Name_Id;
   Platform_Bench_Name                  : Name_Id;
   Platform_Native_Compcert_Name        : Name_Id;
   Platform_LINUX32_Name                : Name_Id;
   Platform_Win32_Name                  : Name_Id;
   Platform_LINUX32_Xenomai_Native_Name : Name_Id;
   Platform_LINUX32_Xenomai_Posix_Name  : Name_Id;
   Platform_LINUX64_Name                : Name_Id;
   Platform_NDS_RTEMS_Name              : Name_Id;
   Platform_NDS_RTEMS_POSIX_Name        : Name_Id;
   Platform_Gumstix_RTEMS_Name          : Name_Id;
   Platform_Gumstix_RTEMS_POSIX_Name    : Name_Id;
   Platform_LEON_RTEMS_Name             : Name_Id;
   Platform_LEON_RTEMS_POSIX_Name       : Name_Id;
   Platform_X86_LINUXTASTE_Name         : Name_Id;
   Platform_X86_RTEMS_Name              : Name_Id;
   Platform_X86_RTEMS_POSIX_Name        : Name_Id;
   Platform_LEON_GNAT_Name              : Name_Id;
   Platform_LEON_ORK_Name               : Name_Id;
   Platform_LEON3_SCOC3_Name            : Name_Id;
   Platform_LEON3_XM3_Name              : Name_Id;
   Platform_LEON3_Xtratum_Name          : Name_Id;
   Platform_ERC32_ORK_Name              : Name_Id;
   Platform_ARM_DSLINUX_Name            : Name_Id;
   Platform_ARM_N770_Name               : Name_Id;
   Platform_ARM_CrazyFlie_Name          : Name_Id;
   Platform_MARTE_OS_Name               : Name_Id;
   Platform_Vxworks_Name                : Name_Id;
   Platform_GNAT_Runtime_Name             : Name_Id;

   Transport_BSD_Sockets_Name : Name_Id;
   Transport_SpaceWire_Name   : Name_Id;

   Protocol_IIOP_Name : Name_Id;
   Protocol_DIOP_Name : Name_Id;

   Provided_Virtual_Bus_Class       : Name_Id;
   Allowed_Connection_Binding_Class : Name_Id;
   Compute_Execution_Time           : Name_Id;
   Execution_Time                   : Name_Id;
   Compute_Deadline                 : Name_Id;

   Core_Id : Name_Id;

   --------------------
   -- SEI properties --
   --------------------

   SEI_Wait_For_All_Events : Name_Id;
   SEI_Stream_Miss_Rate    : Name_Id;

   ----------------------
   -- Scade properties --
   ----------------------

   Scade_Signal_Name : Name_Id;

   --------------------
   -- POK properties --
   --------------------

   POK_Arch_x86_Name         : Name_Id;
   POK_BSP_x86_qemu_Name     : Name_Id;
   POK_BSP_x86_qemu_vmm_Name : Name_Id;
   POK_Arch_Sparc_Name       : Name_Id;
   POK_BSP_Leon_Name         : Name_Id;
   POK_Arch_ppc_Name         : Name_Id;
   POK_BSP_prep_Name         : Name_Id;
   POK_Needed_Memory_Size    : Name_Id;
   POK_BSP                   : Name_Id;
   POK_Arch                  : Name_Id;
   POK_Source_Location       : Name_Id;
   POK_Timeslice             : Name_Id;
   POK_Security_Level        : Name_Id;
   POK_Mils_Verified         : Name_Id;
   POK_Refresh_Time          : Name_Id;
   POK_Scheduler             : Name_Id;
   POK_Scheduler_RMS_Name    : Name_Id;
   POK_Scheduler_EDF_Name    : Name_Id;
   POK_Scheduler_RR_Name     : Name_Id;
   POK_Scheduler_LLF_Name    : Name_Id;
   POK_Scheduler_Static_Name : Name_Id;
   POK_Slots                 : Name_Id;
   POK_Slots_Allocation      : Name_Id;
   POK_Major_Frame           : Name_Id;

   POK_Recovery_Errors                             : Name_Id;
   POK_Recovery_Error_Deadline                     : Name_Id;
   POK_Recovery_Error_Application                  : Name_Id;
   POK_Recovery_Error_Numeric                      : Name_Id;
   POK_Recovery_Error_Request                      : Name_Id;
   POK_Recovery_Error_Stack                        : Name_Id;
   POK_Recovery_Error_Memory                       : Name_Id;
   POK_Recovery_Error_Hardware                     : Name_Id;
   POK_Recovery_Error_Power                        : Name_Id;
   POK_Recovery_Error_Partition_Conf               : Name_Id;
   POK_Recovery_Error_Partition_Init               : Name_Id;
   POK_Recovery_Error_Partition_Sched              : Name_Id;
   POK_Recovery_Error_Partition_Proc               : Name_Id;
   POK_Recovery_Error_Kernel_Init                  : Name_Id;
   POK_Recovery_Error_Kernel_Sched                 : Name_Id;
   POK_Recovery_Actions                            : Name_Id;
   POK_Recovery_Action_Ignore                      : Name_Id;
   POK_Recovery_Action_Confirm                     : Name_Id;
   POK_Recovery_Action_Thread_Restart              : Name_Id;
   POK_Recovery_Action_Thread_Stop_And_Start_Other : Name_Id;
   POK_Recovery_Action_Thread_Stop                 : Name_Id;
   POK_Recovery_Action_Partition_Restart           : Name_Id;
   POK_Recovery_Action_Partition_Stop              : Name_Id;
   POK_Recovery_Action_Kernel_Stop                 : Name_Id;
   POK_Recovery_Action_Kernel_Restart              : Name_Id;
   POK_Recovery_Action_Nothing                     : Name_Id;

   -------------------------
   -- ARINC653 properties --
   -------------------------

   ARINC653_Module_Major_Frame               : Name_Id;
   ARINC653_Partition_Slots                  : Name_Id;
   ARINC653_Slots_Allocation                 : Name_Id;
   ARINC653_Sampling_Refresh_Period          : Name_Id;
   ARINC653_Timeout                          : Name_Id;
   ARINC653_Queuing_Discipline_Name          : Name_Id;
   ARINC653_Queuing_Discipline_Fifo_Name     : Name_Id;
   ARINC653_Queuing_Discipline_Priority_Name : Name_Id;
   ARINC653_Access_Type_Name                 : Name_Id;
   ARINC653_Access_Type_Read_Name            : Name_Id;
   ARINC653_Access_Type_Write_Name           : Name_Id;
   ARINC653_Access_Type_Read_Write_Name      : Name_Id;
   ARINC653_Memory_Kind_Name                 : Name_Id;
   ARINC653_Memory_Kind_Code_Name            : Name_Id;
   ARINC653_Memory_Kind_Data_Name            : Name_Id;

   ARINC653_Actions_Name                             : Name_Id;
   ARINC653_Module_Recovery_Actions_Name             : Name_Id;
   ARINC653_Partition_Recovery_Actions_Name          : Name_Id;
   ARINC653_Process_Recovery_Actions_Name            : Name_Id;
   ARINC653_Action_Ignore_Name                       : Name_Id;
   ARINC653_Action_Confirm_Name                      : Name_Id;
   ARINC653_Action_Partition_Stop_Name               : Name_Id;
   ARINC653_Action_Module_Stop_Name                  : Name_Id;
   ARINC653_Action_Process_Stop_Name                 : Name_Id;
   ARINC653_Action_Process_Stop_And_Start_Other_Name : Name_Id;
   ARINC653_Action_Process_Restart_Name              : Name_Id;
   ARINC653_Action_Partition_Restart_Name            : Name_Id;
   ARINC653_Action_Cold_Restart_Name                 : Name_Id;
   ARINC653_Action_Warm_Restart_Name                 : Name_Id;
   ARINC653_Action_Module_Restart_Name               : Name_Id;
   ARINC653_Action_Nothing_Name                      : Name_Id;
   ARINC653_Action_Reset_Name                        : Name_Id;
   ARINC653_Action_Stop_Name                         : Name_Id;

   ARINC653_Errors_Name                     : Name_Id;
   ARINC653_Error_Module_Init_Name          : Name_Id;
   ARINC653_Error_Module_Config_Name        : Name_Id;
   ARINC653_Error_Module_Scheduling_Name    : Name_Id;
   ARINC653_Error_Partition_Config_Name     : Name_Id;
   ARINC653_Error_Partition_Init_Name       : Name_Id;
   ARINC653_Error_Partition_Scheduling_Name : Name_Id;
   ARINC653_Error_Partition_Handler_Name    : Name_Id;
   ARINC653_Error_Deadline_Miss_Name        : Name_Id;
   ARINC653_Error_Application_Name          : Name_Id;
   ARINC653_Error_Numeric_Name              : Name_Id;
   ARINC653_Error_Invalid_Request_Name      : Name_Id;
   ARINC653_Error_Stack_Overflow_Name       : Name_Id;
   ARINC653_Error_Memory_Violation_Name     : Name_Id;
   ARINC653_Error_Hardware_Fault_Name       : Name_Id;
   ARINC653_Error_Power_Fail_Name           : Name_Id;

   function Get_Size_Property_Value
     (C             : Node_Id;
      Property_Name : Name_Id) return Size_Type;
   --  Code factorization between thread and data interrogators

   function Get_Compute_Entrypoint
     (E       : Node_Id;
      In_Mode : Name_Id := No_Name) return Name_Id;
   function Get_Compute_Entrypoint
     (E       : Node_Id;
      In_Mode : Name_Id := No_Name) return Node_Id;
   --  Code factorization between thread and port interrogators
   --  Note that in case of call sequence reference,
   --  it will return the call sequence's single (by construction)
   --  subprogram call

   function Is_Defined_Entrypoint_Property
     (E       : Node_Id;
      In_Mode : Name_Id := No_Name) return Boolean;

   function Get_Time_Property_Value
     (E             : Node_Id;
      Property_Name : Name_Id) return Time_Type;
   --  Return the value of the property "Property_Name" whose AADL
   --  type is Time.

   function Get_Priority (E : Node_Id) return Unsigned_Long_Long;
   --  Code factorization between thread and data components

   -----------------------------
   -- Get_Size_Property_Value --
   -----------------------------

   function Get_Size_Property_Value
     (C             : Node_Id;
      Property_Name : Name_Id) return Size_Type
   is
      V      : Node_Id;
      U      : Node_Id;
      Result : Size_Type;
      N      : Name_Id;
   begin
      if Is_Defined_Integer_Property (C, Property_Name) then
         V := Get_Value_Of_Property_Association (C, Property_Name);

         if Present (V) and then Present (Unit_Identifier (V)) then
            U := Unit_Identifier (V);

            --  Get the size

            Result.S := Get_Integer_Property (C, Property_Name);

            --  Convert the value to its unit

            N := ATN.Name (U);

            if N = Size_Bit_Name then
               Result.U := Bit;
            elsif N = Size_Byte_Name then
               Result.U := Byte;
            elsif N = Size_Kilo_Byte_Name then
               Result.U := Kilo_Byte;
            elsif N = Size_Mega_Byte_Name then
               Result.U := Mega_Byte;
            elsif N = Size_Giga_Byte_Name then
               Result.U := Giga_Byte;
            elsif N = Size_Tera_Byte_Name then
               Result.U := Tera_Byte;
            else
               Display_Located_Error
                 (AIN.Loc (U),
                  "Wrong unit",
                  Fatal => True);
               return ((0, Bit));
            end if;

            return Result;
         else
            Display_Located_Error
              (AIN.Loc (U),
               "A size without unit",
               Fatal => True);
            return ((0, Bit));
         end if;
      else
         return Null_Size;
      end if;
   end Get_Size_Property_Value;

   ----------------------------
   -- Get_Compute_Entrypoint --
   ----------------------------

   function Get_Compute_Entrypoint
     (E       : Node_Id;
      In_Mode : Name_Id := No_Name) return Name_Id
   is
      Spg_Classifier : Node_Id;
   begin
      if Is_Defined_String_Property
          (E,
           Compute_Entrypoint_Source_Text_Name,
           In_Mode)
      then
         return Get_String_Property
             (E,
              Compute_Entrypoint_Source_Text_Name,
              In_Mode);

      elsif Is_Defined_Property (E, Compute_Entrypoint_Name, In_Mode) then
         Spg_Classifier :=
           Get_Classifier_Property (E, Compute_Entrypoint_Name, In_Mode);
         return Get_Source_Name (Spg_Classifier);
      end if;

      return No_Name;
   end Get_Compute_Entrypoint;

   function Get_Compute_Entrypoint
     (E       : Node_Id;
      In_Mode : Name_Id := No_Name) return Node_Id
   is
   begin
      if Kind (E) = K_Port_Spec_Instance and then not AIN.Is_In (E) then
         Display_Located_Error
           (AIN.Loc (E),
            "Compute entrypoint cannot be specified for OUT-only ports",
            Fatal => True);
      end if;

      if Is_Defined_String_Property
          (E,
           Compute_Entrypoint_Source_Text_Name,
           In_Mode)
      then
         return Get_Property_Association
             (E,
              Compute_Entrypoint_Source_Text_Name,
              In_Mode);

      elsif Is_Defined_Reference_Property
          (E,
           Compute_Entrypoint_Call_Sequence,
           In_Mode)
      then
         return Get_Property_Association
             (E,
              Compute_Entrypoint_Call_Sequence,
              In_Mode);

      elsif Is_Defined_Property (E, Compute_Entrypoint_Name, In_Mode) then
         return Get_Classifier_Property (E, Compute_Entrypoint_Name, In_Mode);

      else
         return No_Node;

      end if;
   end Get_Compute_Entrypoint;

   ------------------------------------
   -- Is_Defined_Entrypoint_Property --
   ------------------------------------

   function Is_Defined_Entrypoint_Property
     (E       : Node_Id;
      In_Mode : Name_Id := No_Name) return Boolean
   is
   begin
      return Is_Defined_String_Property
          (E,
           Compute_Entrypoint_Source_Text_Name,
           In_Mode)
        or else Is_Defined_Reference_Property
          (E,
           Compute_Entrypoint_Call_Sequence,
           In_Mode)
        or else Is_Defined_Property (E, Compute_Entrypoint_Name, In_Mode);
   end Is_Defined_Entrypoint_Property;

   -------------------
   -- Get_Base_Type --
   -------------------

   function Get_Base_Type (D : Node_Id) return List_Id is
      pragma Assert (AINU.Is_Data (D));
   begin
      return Check_And_Get_Property (D, Base_Type);
   end Get_Base_Type;

   ------------------
   -- Get_Code_Set --
   ------------------

   function Get_Code_Set (D : Node_Id) return Unsigned_Long_Long is
      pragma Assert (AINU.Is_Data (D));
   begin
      return Check_And_Get_Property (D, Code_Set);
   end Get_Code_Set;

   ---------------------
   -- Get_Data_Digits --
   ---------------------

   function Get_Data_Digits (D : Node_Id) return Unsigned_Long_Long is
      pragma Assert (Get_Data_Representation (D) = Data_Fixed);
   begin
      return Check_And_Get_Property (D, Data_Digits);
   end Get_Data_Digits;

   --------------------
   -- Get_Data_Scale --
   --------------------

   function Get_Data_Scale (D : Node_Id) return Unsigned_Long_Long is
      pragma Assert (Get_Data_Representation (D) = Data_Fixed);
   begin
      return Check_And_Get_Property (D, Data_Scale);
   end Get_Data_Scale;

   -----------------------------
   -- Get_Data_Representation --
   -----------------------------

   function Get_Data_Representation
     (D : Node_Id) return Supported_Data_Representation
   is
      F      : Node_Id;
      T_Name : Name_Id;
   begin
      pragma Assert (AINU.Is_Data (D));

      if Is_Defined_Enumeration_Property (D, Data_Representation) then
         T_Name := Get_Enumeration_Property (D, Data_Representation);

         --  Although Name_Id is a scalar type, we cannot use a switch
         --  case since the <..>_Name global variables are not (and
         --  cannot be) static.

         if T_Name = Data_Array_Name then
            if not Is_Defined_List_Property (D, Dimension) then
               Display_Located_Error
                 (ATN.Loc (D),
                  "Array types must have one or more dimensions",
                  Fatal => True);
            end if;

            if ATNU.Length (Get_Base_Type (D)) /= 1 then
               Display_Located_Error
                 (ATN.Loc (D),
                  "Array types must have an element type",
                  Fatal => True);
            end if;

            return Data_Array;

         elsif T_Name = Data_Boolean_Name then
            return Data_Boolean;

         elsif T_Name = Data_Character_Name then
            if Get_Code_Set (D) = 16#0# or else Get_Code_Set (D) = 16#1# then
               --  PCS: Portable Character Set
               return Data_Character;
            else
               return Data_Wide_Character;
            end if;

         elsif T_Name = Data_Enum_Name then
            if Get_Enumerators (D)'Length = 0 then
               Display_Located_Error
                 (ATN.Loc (D),
                  "Enumeration type must be assigned an enumerator list",
                  Fatal => True);
            end if;

            return Data_Enum;

         elsif T_Name = Data_Float_Name then
            return Data_Float;

         elsif T_Name = Data_Fixed_Name then
            return Data_Fixed;

         elsif T_Name = Data_Integer_Name then
            return Data_Integer;

         elsif T_Name = Data_String_Name then
            if not Is_Defined_List_Property (D, Dimension) then
               Display_Located_Error
                 (ATN.Loc (D),
                  "String types must have a maximum length",
                  Fatal => True);
            end if;

            if Get_Code_Set (D) = 16#0# or else Get_Code_Set (D) = 16#1# then
               --  PCS: Portable Character Set
               return Data_String;
            else
               return Data_Wide_String;
            end if;

         elsif T_Name = Data_Struct_Name then
            declare
               Fields : constant Name_Array := Get_Element_Names (D);
               Types  : constant List_Id    := Get_Base_Type (D);
            begin
               --  Some trivial case elimination and coherency checking

               if Fields'Length /= ATNU.Length (Types) then
                  Display_Located_Error
                    (AIN.Loc (D),
                     "The number of elements and their corresponding" &
                     " types ar fifferent in this data structure",
                     Fatal => True);
               elsif Fields'Length = 0
                 and then Is_Empty (AIN.Subcomponents (D))
               then
                  Display_Located_Error
                    (AIN.Loc (D),
                     "Data structures must be defined using the" &
                     " subcomponents or the Base_Type/Element_Names" &
                     " properties.",
                     Fatal => True);
               end if;

               if Is_Empty (AIN.Features (D)) then
                  return Data_Struct;
               else
                  --  Check whether it is a protected type

                  F := AIN.First_Node (AIN.Features (D));

                  while Present (F) loop
                     if Kind (F) /= K_Subprogram_Spec_Instance
                       and then Kind (F) /= K_Subcomponent_Access_Instance
                     then
                        Display_Located_Error
                          (AIN.Loc (F),
                           "Unsupported feature kind for data type",
                           Fatal => True);
                     end if;

                     F := AIN.Next_Node (F);
                  end loop;

                  return Data_With_Accessors;
               end if;
            end;

         elsif T_Name = Data_Union_Name then
            return Data_Union;
         else
            Display_Located_Error
              (AIN.Loc (D),
               "Unknown data type",
               Fatal => True);
            return Data_None;
         end if;
      else
         return Data_None;
      end if;
   end Get_Data_Representation;

   -------------------
   -- Get_Dimension --
   -------------------

   function Get_Dimension (D : Node_Id) return ULL_Array is
      pragma Assert (AINU.Is_Data (D));
   begin
      return Check_And_Get_Property (D, Dimension);
   end Get_Dimension;

   -----------------------
   -- Get_Element_Names --
   -----------------------

   function Get_Element_Names (D : Node_Id) return Name_Array is
      pragma Assert (AINU.Is_Data (D));

   begin
      return Check_And_Get_Property (D, Element_Names);
   end Get_Element_Names;

   ---------------------
   -- Get_Enumerators --
   ---------------------

   function Get_Enumerators (D : Node_Id) return Name_Array is
      pragma Assert (AINU.Is_Data (D));
   begin
      return Check_And_Get_Property (D, Enumerators);
   end Get_Enumerators;

   ---------------------------
   -- Get_IEEE754_Precision --
   ---------------------------

   function Get_IEEE754_Precision
     (D : Node_Id) return Supported_IEEE754_Precision
   is
      pragma Assert (AINU.Is_Data (D));

      function Get_IEEE754_Precision_Enumerator is
         new Check_And_Get_Property_Enumerator
        (T => Supported_IEEE754_Precision);

   begin
      return Get_IEEE754_Precision_Enumerator (D, IEEE754_Precision);
   end Get_IEEE754_Precision;

   -----------------------
   -- Get_Initial_Value --
   -----------------------

   function Get_Initial_Value (D : Node_Id) return Name_Array is
      pragma Assert (AINU.Is_Data (D));

   begin
      return Check_And_Get_Property (D, Initial_Value);
   end Get_Initial_Value;

   -----------------------
   -- Get_Integer_Range --
   -----------------------

   function Get_Integer_Range (D : Node_Id) return LL_Array is
      pragma Assert (AINU.Is_Data (D));
   begin
      return Check_And_Get_Property (D, Integer_Range);
   end Get_Integer_Range;

   -------------------------
   -- Get_Mesurement_Unit --
   -------------------------

   function Get_Mesurement_Unit (D : Node_Id) return Name_Id is
      pragma Assert (AINU.Is_Data (D));
   begin
      return Check_And_Get_Property (D, Measurement_Unit);
   end Get_Mesurement_Unit;

   -------------------------------
   -- Get_Number_Representation --
   -------------------------------

   function Get_Number_Representation
     (D : Node_Id) return Supported_Number_Representation
   is
      pragma Assert (AINU.Is_Data (D));

      function Get_Number_Representation_Enumerator is
         new Check_And_Get_Property_Enumerator_With_Default
        (T             => Supported_Number_Representation,
         Default_Value => None);

   begin
      return Get_Number_Representation_Enumerator (D, Number_Representation);
   end Get_Number_Representation;

   --------------------
   -- Get_Real_Range --
   --------------------

   function Get_Real_Range (D : Node_Id) return LD_Array is
      pragma Assert (AINU.Is_Data (D));
   begin
      return Check_And_Get_Property (D, Real_Range);
   end Get_Real_Range;

   -------------------
   -- Get_Data_Size --
   -------------------

   function Get_Data_Size (D : Node_Id) return Size_Type is
      Ret : Size_Type;
   begin
      pragma Assert (AINU.Is_Data (D) or else AINU.Is_Process (D));

      Ret := Get_Size_Property_Value (D, Data_Size);

      if Ret = Null_Size then
         Ret := Get_Size_Property_Value (D, Source_Data_Size);
      end if;

      return Ret;
   end Get_Data_Size;

   -------------------
   -- Get_Code_Size --
   -------------------

   function Get_Code_Size (E : Node_Id) return Size_Type is
   begin
      return Get_Size_Property_Value (E, Code_Size);
   end Get_Code_Size;

   ------------------------------------
   -- Get_Overflow_Handling_Protocol --
   ------------------------------------

   function Get_Overflow_Handling_Protocol
     (P : Node_Id) return Supported_Overflow_Handling_Protocol
   is
      OHP_Name : Name_Id;
   begin
      if Is_Defined_Enumeration_Property (P, Overflow_Handling_Protocol) then
         OHP_Name := Get_Enumeration_Property (P, Overflow_Handling_Protocol);

         if OHP_Name = Overflow_Handling_Protocol_DropOldest_Name then
            return Overflow_Handling_Protocol_DropOldest;
         elsif OHP_Name = Overflow_Handling_Protocol_DropNewest_Name then
            return Overflow_Handling_Protocol_DropNewest;
         elsif OHP_Name = Overflow_Handling_Protocol_Error_Name then
            return Overflow_Handling_Protocol_Error;
         else
            Display_Located_Error
              (AIN.Loc (P),
               "Unknown port overflow handling protocol name",
               Fatal => True);
            return Overflow_Handling_Protocol_DropOldest;
         end if;
      else
         return Overflow_Handling_Protocol_DropOldest;