ErrorLibrary.aadl 6.61 KB
Newer Older
Jerome Legrand's avatar
Jerome Legrand committed
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181
----------------------------------------
-- EMV2 Error Models Library
-- AADL Error Annex (SAE AS-5506/1B) 
-- AADL Inspector
-- Ellidiss Technologies
-- Updated: January 2015
----------------------------------------

PACKAGE errorlibrary
PUBLIC

ANNEX emv2 {**

  ERROR TYPES
    serviceerror : TYPE;
    itemomission : TYPE EXTENDS serviceerror;
    serviceomission : TYPE EXTENDS serviceerror;
    sequenceomission : TYPE EXTENDS serviceerror;
    transientserviceomission : TYPE EXTENDS sequenceomission;
    lateservicestart : TYPE EXTENDS sequenceomission;
    earlyservicetermination : TYPE EXTENDS sequenceomission;
    boundedomissioninterval : TYPE EXTENDS sequenceomission;
    itemcomission : TYPE EXTENDS serviceerror;
    servicecommission : TYPE EXTENDS serviceerror;
    sequencecommission : TYPE EXTENDS serviceerror;
    earlyservicestart : TYPE EXTENDS sequencecommission;
    lateservicetermination : TYPE EXTENDS sequencecommission;
    itemtimingerror : TYPE;
    earlydelivery : TYPE EXTENDS itemtimingerror;
    latedelivery : TYPE EXTENDS itemtimingerror;
    sequencetimingerror : TYPE;
    highrate : TYPE EXTENDS sequencetimingerror;
    lowrate : TYPE EXTENDS sequencetimingerror;
    ratejitter : TYPE EXTENDS sequencetimingerror;
    servicetimingerror : TYPE;
    delayedservice : TYPE EXTENDS servicetimingerror;
    earlyservice : TYPE EXTENDS servicetimingerror;
    itemvalueerror : TYPE;
    undetectablevalueerror : TYPE EXTENDS itemvalueerror;
    detectablevalueerror : TYPE EXTENDS itemvalueerror;
    outofrange : TYPE EXTENDS detectablevalueerror;
    belowrange : TYPE EXTENDS outofrange;
    aboverange : TYPE EXTENDS outofrange;
    outofbounds : TYPE EXTENDS detectablevalueerror;
    sequencevalueerror : TYPE;
    boundedvaluechange : TYPE EXTENDS sequenceerror;
    stuckvalue : TYPE EXTENDS sequenceerror;
    outoforder : TYPE EXTENDS sequenceerror;
    servicevalueerror : TYPE;
    outofcalibration : TYPE EXTENDS servicevalueerror;
    replicationerror : TYPE;
    asymmetricreplicateserror : TYPE EXTENDS replicationerror;
    asymmetricvalue : TYPE EXTENDS asymmetricreplicateserror;
    asymmetricapproximatevalue : TYPE EXTENDS asymmetricvalue;
    asymmetricexactvalue : TYPE EXTENDS asymmetricvalue;
    asymmetrictiming : TYPE EXTENDS asymmetricreplicateserror;
    asymmetricomission : TYPE EXTENDS asymmetricreplicateserror;
    asymmetricitemomission : TYPE EXTENDS asymmetricomission;
    asymmetricserviceomission : TYPE EXTENDS asymmetricomission;
    symmetricreplicateserror : TYPE EXTENDS replicationerror;
    symmetricvalue : TYPE EXTENDS symmetricreplicateserror;
    symmetricapproximatevalue : TYPE EXTENDS symmetricvalue;
    symmetricexactvalue : TYPE EXTENDS symmetricvalue;
    symmetrictiming : TYPE EXTENDS symmetricreplicateserror;
    symmetricomission : TYPE EXTENDS symmetricreplicateserror;
    symmetricitemomission : TYPE EXTENDS symmetricomission;
    symmetricserviceomission : TYPE EXTENDS symmetricomission;
    concurrencyerror : TYPE;
    racecondition : TYPE EXTENDS concurrencyerror;
    readwriterace : TYPE EXTENDS racecondition;
    writewriterace : TYPE EXTENDS racecondition;
    mutexerror : TYPE EXTENDS concurrencyerror;
    deadlock : TYPE EXTENDS mutexerror;
    starvation : TYPE EXTENDS mutexerror;
    authorizationerror : TYPE;
    authenticationerror : TYPE;
    commonerrors : TYPE SET {serviceerror,timingrelatederror,valuerelatederror,replicationerror,concurrencyerror};
    timingrelatederror : TYPE SET {itemtimingerror,sequencetimingerror,servicetimingerror};
    valuerelatederror : TYPE SET {itemvalueerror,sequencevalueerror,servicevalueerror};
    timingerror RENAMES TYPE itemtimingerror;
    rateerror RENAMES TYPE sequencetimingerror;
    earlydata RENAMES TYPE highrate;
    latedata RENAMES TYPE lowrate;
    servicetimeshift RENAMES TYPE servicetimingerror;
    valueerror RENAMES TYPE itemvalueerror;
    incorrectvalue RENAMES TYPE itemvalueerror;
    valuecorruption RENAMES TYPE itemvalueerror;
    badvalue RENAMES TYPE itemvalueerror;
    sequenceerror RENAMES TYPE sequencevalueerror;
    subtlevalueerror RENAMES TYPE undetectablevalueerror;
    benignvalueerror RENAMES TYPE detectablevalueerror;
    subtlevaluecorruption RENAMES TYPE detectablevalueerror;
    inconsistentvalue RENAMES TYPE asymmetricvalue;
    inconsistenttiming RENAMES TYPE asymmetrictiming;
    inconsistentomission RENAMES TYPE asymmetricomission;
    inconsistentitemomission RENAMES TYPE asymmetricitemomission;
    inconsistentserviceomission RENAMES TYPE asymmetricserviceomission;
    asymmetrictransmissive RENAMES TYPE asymmetricvalue;
  END TYPES;

  ERROR BEHAVIOR failstop
  EVENTS
    failure : ERROR EVENT;
  STATES
    operational : INITIAL STATE;
    failstop : STATE;
  TRANSITIONS
    failuretransition : operational -[ Failure ]-> failstop;
  END BEHAVIOR;

  ERROR BEHAVIOR degradedfailstop
  EVENTS
    failure : ERROR EVENT;
  STATES
    operational : INITIAL STATE;
    degraded : STATE;
    failstop : STATE;
  TRANSITIONS
    firstfailure : operational -[ Failure ]-> degraded;
    secondfailure : degraded -[ Failure ]-> failstop;
  END BEHAVIOR;

  ERROR BEHAVIOR failandrecover
  EVENTS
    failure : ERROR EVENT;
    recovery : RECOVER EVENT;
  STATES
    operational : INITIAL STATE;
    failed : STATE;
  TRANSITIONS
    failuretransition : operational -[ Failure ]-> failed;
    recoverytransition : failed -[ Recovery ]-> operational;
  END BEHAVIOR;

  ERROR BEHAVIOR degradedrecovery
  EVENTS
    failure : ERROR EVENT;
    recovery : RECOVER EVENT;
  STATES
    operational : INITIAL STATE;
    degraded : STATE;
    failstop : STATE;
  TRANSITIONS
    firstfailure : operational -[ Failure ]-> degraded;
    recoverytransition : degraded -[ Recovery ]-> operational;
    secondfailure : degraded -[ Failure ]-> failstop;
  END BEHAVIOR;

  ERROR BEHAVIOR permanenttransientfailure
  EVENTS
    failure : ERROR EVENT;
    recovery : RECOVER EVENT;
  STATES
    operational : INITIAL STATE;
    failedtransient : STATE;
    failedpermanent : STATE;
  TRANSITIONS
    failtransition : operational -[ Failure ]-> ( 
      failedtransient WITH EMV2::TransientFailureRatio, 
      failedpermanent WITH OTHERS );
    recoverytransition : failedtransient -[ Recovery ]-> operational;
  END BEHAVIOR;

  ERROR BEHAVIOR failrecoveryfailure
  EVENTS
    failure : ERROR EVENT;
    recovery : RECOVER EVENT;
  STATES
    operational : INITIAL STATE;
    failed : STATE;
    failstop : STATE;
  TRANSITIONS
    failuretransition : operational -[ Failure ]-> failed;
    recoverytransition : failed -[ Recovery ]-> ( 
      operational WITH EMV2::RecoveryFailureRatio, 
      failstop WITH OTHERS );
  END BEHAVIOR;
**};

END errorlibrary;